home *** CD-ROM | disk | FTP | other *** search
/ The Unsorted BBS Collection / thegreatunsorted.tar / thegreatunsorted / misc / dr.str / PG-HC11 1.1.asm < prev    next >
Assembly Source File  |  1992-10-05  |  18KB  |  593 lines
  1. ************************************************************************
  2. * This file has been converted to compile using the Motorola freeware
  3. * cross-assembler.
  4. *
  5. * Jim Speth   10/5/92
  6. * speth@cats.ucsc.edu
  7. *
  8. ************************************************************************
  9.  
  10. *
  11. * Here's version 1.1 of the 68HC11EVB power glove code. The only change
  12. * is that a port of Dave Stampe's hysterisis deglitching code has been
  13. * added. The routines are activated by sending a "+" and deactivated by
  14. * a "-". 
  15. * 
  16. * Please let me know your results...
  17. *
  18. *    -Ron Menelli       12/10/92
  19. *
  20.  
  21. */**********************************************************************
  22. * 
  23. *  Originally "power.c" (c) manfredo 9/91 (manfredo@opal.cs.tu-berlin.de)
  24. *  Developed on an ATARI 1040ST with TC 1.1 using a logic analyzer to get
  25. *  the correct timings.
  26. * 
  27. ***********************************************************************/
  28. */*********************************************************************
  29. *             ported to PC compatibles by
  30. *                Greg Alt 10/91
  31. * 
  32. *               galt@peruvian.utah.edu
  33. *            or galt@es.dsd.com
  34. * 
  35. ***********************************************************************/
  36. */*********************************************************************
  37. *
  38. * Substantially rewritten by Dave Stampe (c) 1991: PWRFILT.C
  39. *  No cash, no warranty, no flames.
  40. *  This stuff works great, so gimme credit.
  41. *
  42. * Goals <achieved> were:
  43. *
  44. *  Higher speed, smaller code.
  45. *  Polled operation is now possible.
  46. *  Graphics test (VGA)
  47. *  Noise reduction added, gets rid of 99.5% of noise with NO DELAY!
  48. *
  49. *  This runs on a 486/25 with an i/o card. 
  50. *  Someone should adapt it for the usual printer port adapter.
  51. *  It was compiled with Turbo C++ 2.0 but will probably
  52. *  work on any Turbo C directly. MSC will need library calls checked.
  53. *
  54. *
  55. * dstamp@watserv1.uwaterloo.ca          17/10/91
  56. ***********************************************************************/
  57. *
  58. *
  59. * 68HC11 version by Ron Menelli, 10/23/91
  60. *
  61. * A million thanks to the above people for taking this project as far
  62. * as it has gone! This version runs on the MC68HC11 processor, specifically
  63. * Motorola's MC68HC11EVB board. The assembler I used was Matt Dillon's
  64. * DASM for the Amiga - this code will have to be converted a bit to be
  65. * used on Motorola's freeware assembler.
  66. *
  67. * As it stands, this code is a direct port of Dave Stampe's code minus
  68. * the IBM specific stuff (VGA, for example). The way this code works is
  69. * by sending the data received from the Power Glove over the serial port
  70. * at 9600 baud. By sending single character commands, the serial port
  71. * action can be controlled as follows:
  72. *
  73. *       Send    Action
  74. *       ====    =========
  75. *        C      Start continuous mode - send every time the glove is read.
  76. *               The data is sent with a certain byte preceding it as a
  77. *               flag marking the beginning. The format I have used is:
  78. *
  79. *                   A0 X Y Z rot fingers keys
  80. *
  81. *                   ^
  82. *                   +--- Flag character (A0 used for old time's sake!)
  83. *
  84. *        R      Start request mode - send the 6 byte data packet when
  85. *               requested by user. Format is the same as above, minus
  86. *               the flag character.
  87. *
  88. *        ?      In request mode, this causes the controller to report
  89. *               the current glove data.
  90. *
  91. *        +      Turns on hysterisis deglitching mode (new for 1.1)
  92. *
  93. *        -      Turns off hysterisis deglitching mode (new for 1.1)
  94. *
  95. * Please send me any suggestions you have regarding improvements to this
  96. * code!
  97. *
  98. * -Ron Menelli  menelli@tellabs.com
  99. *
  100.  
  101. *************************************************************
  102. **** Must be set depending on type of controller board! *****
  103. *************************************************************
  104. * (If your using the homebrew board, you must ALSO change the
  105. *   last couple of lines in the program.)
  106. *************************************************************
  107. *
  108. * Address of beginning of program:
  109. *
  110. *      $D000 : beginning of RAM for EVB ($D800 is common also)
  111. *      $B600 : beginning of RAM for EVBU
  112. *      $F800 : for homebrew version
  113. *
  114.  
  115.     ORG         $D800           ; Jump to this address to start
  116.  
  117. *
  118. * RAM allocation
  119. *
  120.  
  121. BITCNT      EQU     $0000
  122. BYTECNT     EQU     $0001
  123. GLOVEFLAG   EQU     $0002       ; Flag byte for continuous mode
  124. GLOVEDATA   EQU     $0003       ; 7 byte array
  125. UNREADY     EQU     $0009
  126. MODEFLAG    EQU     $000A       ; Mode flag - continuous or request
  127. OX          EQU     $000B       ; The following are for hysterisis calculations
  128. OY          EQU     $000D
  129. TMP         EQU     $000F
  130. DEGLFLAG    EQU     $0011       ; Deglitching mode flag
  131.  
  132. *
  133. * Port A definitions
  134. *
  135. * bit 0 - Data in
  136. * bit 4 - Clock out
  137. * bit 5 - Latch out
  138. *
  139.  
  140. PORTA       EQU     $1000
  141. PACTL       EQU     $1026
  142. GDATA       EQU     $01
  143. GCLOCK      EQU     $10
  144. GLATCH      EQU     $20
  145. GCLOLAT     EQU     $30
  146.  
  147. *
  148. * Serial port definitions
  149. *
  150.  
  151. BAUD        EQU     $102B
  152. SCCR1       EQU     $102C
  153. SCCR2       EQU     $102D
  154. SCSR        EQU     $102E
  155. SCDR        EQU     $102F
  156.  
  157. *
  158. * Timing constants (for an 8Mhz crystal)
  159. *
  160.  
  161. D2BYTES     EQU     30          ; 96us
  162. D2SLOW      EQU     700         ; ~= 2100us
  163.  
  164. *
  165. * Variables for hysterisis
  166. *
  167.  
  168. XHYST       EQU     2
  169. YHYST       EQU     2
  170.  
  171. *
  172. *Variables for deglitching
  173. *
  174.  
  175. XACC        EQU     8
  176. YACC        EQU     8
  177. XXTEND      EQU     2
  178. YXTEND      EQU     1
  179.  
  180. * Other stuff
  181.  
  182. CONTMODE    EQU     0           ; Continuous mode
  183. REQMODE     EQU     1           ; Request mode
  184. CONTCHAR    EQU     'C          ; Character to request cont. mode
  185. REQCHAR     EQU     'R          ; Character to request request mode
  186. QUERYCHAR   EQU     '?          ; Character to request a data packet
  187. *                                     Only valid in request mode
  188. DEGLCHAR    EQU     '+          ; Character to request deglitching mode
  189. NDGLCHAR    EQU     '-          ; Character to turn off deglitching mode
  190. FLAGCHAR    EQU     $A0         ; Flag indicating beginning of packet in continuous mode
  191.  
  192. *
  193. * ***********************
  194. * * Program begins here *
  195. * ***********************
  196. *
  197.  
  198. INIT:       LDS     #$00FF      ; Initialize stack pointer
  199.  
  200.             LDAA    #0          ; Disable pulse accumulator on port A
  201.             STAA    PACTL
  202.  
  203.             LDAA    #$01        ; Set EVB to serial receive normally
  204.             STAA    $4000
  205.  
  206.             LDAA    #$30        ; Set serial port for 9600 baud, (using 8 MHz XTAL)
  207.             STAA    BAUD
  208.             LDAA    #$0C        ; Transmit & receive enable
  209.             STAA    SCCR2
  210.  
  211.             LDAA    #FLAGCHAR   ; Set up flag character in buffer
  212.             STAA    GLOVEFLAG
  213.  
  214.             LDAA    #CONTMODE   ; Start in continuous mode
  215.             STAA    MODEFLAG
  216.  
  217.             LDAA    #$FF        ; Start in deglitching mode
  218.             STAA    DEGLFLAG
  219.  
  220.             JSR     INITVAR     ; Initialize deglitching variables
  221.  
  222. INITGLOVE:  JSR     HIRES       ; Set hi-res mode
  223.  
  224. *
  225. * *********************
  226. * * Main program loop *
  227. * *********************
  228. *
  229.  
  230. MAIN:       LDAA    #0          ; Zero the retry counter
  231.             STAA    UNREADY
  232.             LDX     #D2SLOW     ; Wait a while
  233.             JSR     DELAY
  234.  
  235. CHECKRDY:   JSR     GETBYTE     ; Check to see if glove is ready
  236.             CMPA    #$A0        ; Is it A0 (the start of the sequence?)
  237.             BEQ     READDATA    ; Yes, read the rest of the data sequence
  238.  
  239.             INC     UNREADY     ; Increment retry counter
  240.             BEQ     INITGLOVE   ; If 256 tries, initialize the glove again
  241.  
  242.             LDX     #D2SLOW     ; Wait and try again
  243.             JSR     DELAY
  244.             BRA     CHECKRDY
  245.  
  246. READDATA:   LDY     #GLOVEDATA
  247.             JSR     GETGLOVE    ; Read glove data into buffer
  248.  
  249.             LDAA    DEGLFLAG    ; Check to see if we're supposed to deglitch
  250.             BEQ     CHECKSER    ; No - go on to keypresses
  251.  
  252.             LDY     #GLOVEDATA
  253.             JSR     DOHYST      ; *** Do hysterisis deglitch
  254.  
  255. CHECKSER:   LDAA    SCSR        ; Check serial port receive status
  256.             ANDA    #$20
  257.             BEQ     CHECKMODE
  258.  
  259.             LDAA    SCDR        ; Character received - check it
  260.  
  261.             CMPA    #QUERYCHAR  ; Is it the query character?
  262.             BNE     NOTQRYCH    ; No - skip this
  263.             LDAA    MODEFLAG    ; Yes - check to see what mode we're in
  264.             CMPA    #REQMODE    ; If not in request mode, skip this
  265.             BNE     CHECKMODE
  266.             LDY     #GLOVEDATA  ; Send 6 bytes over the serial port
  267.             LDAB    #6
  268.             JSR     SENDSER     ; This does our pausing for us (6.25 ms)
  269.             BRA     MAIN        ; No need to continue checking
  270.             
  271. NOTQRYCH:   CMPA    #CONTCHAR   ; Is it the cont. mode activator?
  272.             BNE     NOTCONTCH   ; No - skip this
  273.             LDAA    #CONTMODE   ; Yes - set continuous mode
  274.             STAA    MODEFLAG
  275.             BRA     CHECKMODE
  276.  
  277. NOTCONTCH:  CMPA    #REQCHAR    ; Is it the request mode activator?
  278.             BNE     NOTREQCH    ; No - skip this
  279.             LDAA    #REQMODE    ; Yes - set request mode
  280.             STAA    MODEFLAG
  281.             BRA     WAIT        ; No need to continue checking
  282.  
  283. NOTREQCH:   CMPA    #DEGLCHAR   ; Is it the deglitching on character?
  284.             BNE     NOTDEGCH    ; No - skip this
  285.             LDAA    #$FF        ; Yes - set the deglitching flag
  286.             STAA    DEGLFLAG
  287.             BRA     WAIT
  288.  
  289. NOTDEGCH:   CMPA    #NDGLCHAR   ; Is it the deglitching off character?
  290.             BNE     CHECKMODE   ; No - skip this
  291.             LDAA    #0          ; Yes - clear the deglitching flag
  292.             STAA    DEGLFLAG
  293.             BRA     WAIT
  294.  
  295. CHECKMODE:  LDAA    MODEFLAG    ; Check the mode flag
  296.             CMPA    #CONTMODE   ; Is it continuous mode?
  297.             BNE     WAIT        ; No - wait and start the loop again
  298.             LDY     #GLOVEFLAG  ; Send data (6 + Flag) over serial port
  299.             LDAB    #7
  300.             JSR     SENDSER     ; This provides approx. 7.29 ms of delay at 9600 baud
  301.             JMP     MAIN
  302.  
  303. WAIT:       LDX     #D2SLOW     ; Wait a while before continuing
  304.             JSR     DELAY
  305.             JMP     MAIN
  306.  
  307. *
  308. * **************************************
  309. * *          Delay subroutine          *
  310. * * (Delay proportional to value in X) *
  311. * **************************************
  312. *
  313.  
  314. DELAY:      DEX
  315.             BNE     DELAY
  316.             RTS
  317.  
  318. *
  319. * *******************
  320. * * Set hi-res mode *
  321. * *******************
  322. *
  323.  
  324. HIRES:      LDAB    #GCLOCK     ; Dummy read 4 dummy bits from glove
  325.             STAB    PORTA       ; Set Clock = 1, Latch = 0
  326.             LDAB    #GCLOLAT    ; Set Clock = 1, Latch = 1
  327.             STAB    PORTA
  328.             NOP                 ; Delay 3us
  329.             NOP
  330.             NOP
  331.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  332.             STAB    PORTA
  333.  
  334.             NOP                 ; Delay 3us
  335.             NOP
  336.             NOP
  337.             LDAB    #0          ; Set Clock = 0, Latch = 0
  338.             STAB    PORTA
  339.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  340.             STAB    PORTA
  341.             NOP                 ; Delay 3us
  342.             NOP
  343.             NOP
  344.             LDAB    #0          ; Set Clock = 0, Latch = 0
  345.             STAB    PORTA
  346.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  347.             STAB    PORTA
  348.             NOP                 ; Delay 3us
  349.             NOP
  350.             NOP
  351.             LDAB    #0          ; Set Clock = 0, Latch = 0
  352.             STAB    PORTA
  353.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  354.             STAB    PORTA
  355.             NOP                 ; Delay 3us
  356.             NOP
  357.             NOP
  358.             LDAB    #0          ; Set Clock = 0, Latch = 0
  359.             STAB    PORTA
  360.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  361.             STAB    PORTA
  362.  
  363.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  364.             STAB    PORTA
  365.             LDX     #2402       ; Delay 7212us
  366.             JSR     DELAY
  367.  
  368.             LDAB    #GCLOLAT    ; Set Clock = 1, Latch = 1
  369.             STAB    PORTA
  370.             LDX     #752        ; Delay 2260us
  371.             JSR     DELAY
  372.  
  373.             LDAA    #7
  374.             STAA    BYTECNT
  375.             LDY     #HRCODE     ; Send the 7 byte code
  376. BYTELOOP:   LDAA    #8
  377.             STAA    BITCNT
  378.             LDAA    0,Y
  379. BITLOOP:    LSLA
  380.             BCC     BITOFF
  381.             LDAB    #GCLOLAT    ; Set Clock = 1, Latch = 1
  382.             STAB    PORTA
  383.             LDAB    #GLATCH     ; Set Clock = 0, Latch = 1
  384.             STAB    PORTA
  385.             LDAB    #GCLOLAT    ; Set Clock = 1, Latch = 1
  386.             STAB    PORTA
  387.             BRA     NEXTLOOP
  388. BITOFF:     LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  389.             STAB    PORTA
  390.             LDAB    #0          ; Set Clock = 0, Latch = 0
  391.             STAB    PORTA
  392.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  393.             STAB    PORTA
  394. NEXTLOOP:   NOP                 ; Delay 3us
  395.             NOP
  396.             NOP
  397.             DEC     BITCNT
  398.             BNE     BITLOOP
  399.  
  400.             LDX     #D2BYTES
  401.             JSR     DELAY
  402.             INY
  403.             DEC     BYTECNT
  404.             BNE     BYTELOOP
  405.  
  406.             LDX     #296        ; Delay 892us
  407.             JSR     DELAY
  408.  
  409.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  410.             STAB    PORTA
  411.             LDX     #20000      ; Delay a "long time"
  412.             JSR     DELAY
  413.             RTS
  414.  
  415. *
  416. * Glove initialization bytes
  417. * Was HRCODE:     dc.b    $06,$C1,$08,$00,$02,$FF,$01
  418. *
  419.  
  420. HRCODE:     FCB     $06,$C1,$08,$00,$02,$FF,$01
  421.  
  422. *
  423. * *******************************************
  424. * *        Get the 6 byte data packet       *
  425. * * (Places data in buffer pointed to by Y) *
  426. * *******************************************
  427. *
  428.  
  429. GETGLOVE:   JSR     GETBYTE     ; Get each byte consecutively
  430.             STAA    0,Y         ; and store in memory
  431.             INY
  432.             LDX     #D2BYTES
  433.             JSR     DELAY
  434.  
  435.             JSR     GETBYTE
  436.             STAA    0,Y
  437.             INY
  438.             LDX     #D2BYTES
  439.             JSR     DELAY
  440.  
  441.             JSR     GETBYTE
  442.             STAA    0,Y
  443.             INY
  444.             LDX     #D2BYTES
  445.             JSR     DELAY
  446.  
  447.             JSR     GETBYTE
  448.             STAA    0,Y
  449.             INY
  450.             LDX     #D2BYTES
  451.             JSR     DELAY
  452.  
  453.             JSR     GETBYTE
  454.             STAA    0,Y
  455.             INY
  456.             LDX     #D2BYTES
  457.             JSR     DELAY
  458.  
  459.             JSR     GETBYTE
  460.             STAA    0,Y
  461.             LDX     #D2BYTES
  462.             JSR     DELAY
  463.  
  464.             JSR     GETBYTE     ; Throw away last two bytes
  465.             LDX     #D2BYTES
  466.             JSR     DELAY
  467.             JSR     GETBYTE
  468.             RTS
  469.  
  470. *
  471. * ************************
  472. * * Initialize variables *
  473. * ************************
  474. *
  475. INITVAR:    LDD     #0          ; Set all variables to 0
  476.             STD     OX          ; First hysterisis variables
  477.             STD     OY
  478.             RTS
  479.  
  480. *
  481. * *****************************
  482. * * Get a byte from the glove *
  483. * *    (Returns byte in A)    *
  484. * *****************************
  485. *
  486.  
  487. GETBYTE:    LDAB    #GCLOCK     ; Pulse the latch line
  488.             STAB    PORTA       ; Set Clock = 1, Latch = 0
  489.             LDAB    #GCLOLAT    ; Set Clock = 1, Latch = 1
  490.             STAB    PORTA
  491.             NOP                 ; Delay 3us
  492.             NOP
  493.             NOP
  494.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  495.             STAB    PORTA
  496.  
  497.             LDAA    #8
  498.             STAA    BITCNT
  499.  
  500. GETLOOP:    LSLA                ; Read 8 bits sequentially
  501.             LDAB    PORTA
  502.             ANDB    #GDATA      ; Mask off other bits
  503.             ABA                 ; Assemble the data byte
  504.             LDAB    #0          ; Set Clock = 0, Latch = 0
  505.             STAB    PORTA
  506.             LDAB    #GCLOCK     ; Set Clock = 1, Latch = 0
  507.             STAB    PORTA
  508.             DEC     BITCNT
  509.             BNE     GETLOOP
  510.  
  511.             RTS
  512.  
  513. *
  514. * *****************************
  515. * *    Hysterisis deglitch    *
  516. * * (Y points to data buffer) *
  517. * *****************************
  518. *
  519. DOHYST:     LDAA    5,Y         ; Check for center button
  520.             BNE     NOCENTER
  521.             JSR     INITVAR     ; If so, clear variables
  522.  
  523. NOCENTER:   CLRA
  524.             LDAB    0,Y         ; Begin hysterisis for X
  525.             BPL     NOXTNDHX    ; Sign extend B reg. into D
  526.             COMA
  527. NOXTNDHX:   STD     TMP
  528.             SUBD    OX
  529.             CPD     #XHYST
  530.             BLE     HYSTX1
  531.             LDD     TMP
  532.             SUBD    #XHYST
  533.             STD     OX
  534. HYSTX1:     LDD     OX
  535.             SUBD    TMP
  536.             CPD     #XHYST
  537.             BLE     HYSTY1
  538.             LDD     TMP
  539.             ADDD    #XHYST
  540.             STD     OX
  541.  
  542. HYSTY1:     CLRA
  543.             LDAB    1,Y         ; Begin hysterisis for Y
  544.             BPL     NOXTNDHY    ; Sign extend B reg. into D
  545.             COMA
  546. NOXTNDHY:   STD     TMP
  547.             SUBD    OY
  548.             CPD     #YHYST
  549.             BLE     HYSTY2
  550.             LDD     TMP
  551.             SUBD    #YHYST
  552.             STD     OY
  553. HYSTY2:     LDD     OY
  554.             SUBD    TMP
  555.             CPD     #YHYST
  556.             BLE     HYSTDONE
  557.             LDD     TMP
  558.             ADDD    #YHYST
  559.             STD     OY
  560.  
  561. HYSTDONE:   LDAA    OX+1        ; Put values back
  562.             STAA    0,Y
  563.             LDAA    OY+1
  564.             STAA    1,Y
  565.             RTS
  566.  
  567. *
  568. * ***********************************************
  569. * * Send an X byte packet over the serial port  *
  570. * * (Y contains the address of the data buffer, *
  571. * *  B contains the number of bytes to send)    *
  572. * ***********************************************
  573. *
  574.  
  575. SENDSER:    LDAA    SCSR        ; Check status register for Tx ready
  576.             ANDA    #$80
  577.             BEQ     SENDSER     ; Try again if not ready
  578.  
  579.             LDAA    0,Y         ; Send byte to the serial port
  580.             STAA    SCDR
  581.  
  582.             INY                 ; Move to next data byte
  583.             DECB
  584.             BNE     SENDSER     ; Send next byte if not done
  585.  
  586.             RTS
  587.  
  588. *
  589. * Uncomment these next lines for the homebrew board:
  590. *
  591. *    ORG     $FFFA               ; Reset vectors for standalone board
  592. *    FDB     $F800,$F800,$F800
  593.